pict: Support loading of PNGs.

* pict.scm (pict-from-file): Detect and support PNGs.
(png-size): New procedure.
* pict/base64.scm: New file.

2 files changed, 306 insertions, 12 deletions

diff --git a/pict.scm b/pict.scm
index c755aed..b26a60d 100644
--- a/pict.scm
+++ b/pict.scm
@@ -19,10 +19,13 @@
 
 (define-module (pict)
   #:use-module (pict sxml)
+  #:use-module (pict base64)
   #:use-module ((sxml simple) #:hide (xml->sxml))
   #:use-module (sxml transform)
   #:use-module (sxml fold)
   #:use-module ((sxml xpath) #:hide (filter))
+  #:use-module (ice-9 binary-ports)
+  #:use-module (rnrs bytevectors)
   #:use-module (srfi srfi-1)
   #:use-module (srfi srfi-9)
   #:use-module (srfi srfi-9 gnu)
@@ -148,21 +151,56 @@ list VALS."
          '(0 . ())
          (cons 0 vals))))
 
+(define (png-size file-name)
+  "Return two values: width and height of the PNG file at FILE-NAME."
+  (define (bv->size bv)
+    (car (bytevector->uint-list bv (endianness big) 4)))
+  (call-with-input-file file-name
+    (lambda (port)
+      (get-bytevector-n port 8) ; throw away header
+      (get-bytevector-n port 4) ; throw away first chunk length
+      (if (bytevector=? (get-bytevector-n port 4)
+                        #vu8(73 72 68 82))   ; IHDR
+          (values
+           (bv->size (get-bytevector-n port 4))  ; width
+           (bv->size (get-bytevector-n port 4))) ; height
+          (values #f #f)))))
+
 (define (pict-from-file file-name)
   "Attempt to read FILE-NAME, convert its contents to SXML and wrap it
 in a <PICT> record.  If this fails return #F."
-  (catch 'parser-error
-    (lambda ()
-      (make-pict
-       (match (call-with-input-file file-name xml->sxml)
-         (('*TOP* ('*PI* . rest) svg) svg)
-         (('*TOP* svg) svg))))
-    (lambda _
-      (format (current-error-port)
-              "Failed to parse picture from file `~a'.~%\
-Is this really an SVG file?~%"
-              file-name)
-      #f)))
+  (let ((header (call-with-input-file file-name
+                  (lambda (port) (get-bytevector-n port 8)))))
+    (make-pict
+     (match header
+       (#vu8(137 80 78 71 13 10 26 10) ; PNG
+        (call-with-values
+            (lambda () (png-size file-name))
+          (lambda (width height)
+            `(svg (@ (width ,width)
+                     (height ,height)
+                     (xmlns "http://www.w3.org/2000/svg")
+                     (xmlns:xlink "http://www.w3.org/1999/xlink"))
+                  (image (@ (width ,width)
+                            (height ,height)
+                            (xlink:href
+                             ,(string-append
+                               "data:image/png;base64,"
+                               (call-with-input-file file-name
+                                 (lambda (port)
+                                   (base64-encode (get-bytevector-all port)))
+                                 #:binary #t)))))))))
+       (_ ; Assume SVG
+        (catch 'parser-error
+          (lambda ()
+            (match (call-with-input-file file-name xml->sxml)
+              (('*TOP* ('*PI* . rest) svg) svg)
+              (('*TOP* svg) svg)))
+          (lambda args
+            (format (current-error-port)
+                    "Failed to load picture from file `~a'.~%Only PNG or SVG are supported.~%~a~%"
+                    file-name args)
+            #f)))))))
 
 
 ;;; SXML utilities
diff --git a/pict/base64.scm b/pict/base64.scm
new file mode 100644
index 0000000..21c0d26
--- /dev/null
+++ b/pict/base64.scm
@@ -0,0 +1,256 @@
+;; -*- mode: scheme; coding: utf-8 -*-
+;;
+;; This module was taken from the Guix sources and renamed to
+;; (pict base64) on February 9, 2019.
+;;
+;; This module was renamed from (weinholt text base64 (1 0 20100612)) to
+;; (guix base64) by Nikita Karetnikov <nikita@karetnikov.org> on
+;; February 12, 2014.
+;;
+;; Some optimizations made by Ludovic Courtès <ludo@gnu.org>, 2015.
+;; Turned into a Guile module (instead of R6RS).
+;;
+;; This program is free software: you can redistribute it and/or modify
+;; it under the terms of the GNU General Public License as published by
+;; the Free Software Foundation, either version 3 of the License, or
+;; (at your option) any later version.
+;;
+;; This program is distributed in the hope that it will be useful,
+;; but WITHOUT ANY WARRANTY; without even the implied warranty of
+;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;; GNU General Public License for more details.
+;;
+;; You should have received a copy of the GNU General Public License
+;; along with this program.  If not, see <http://www.gnu.org/licenses/>.
+;;
+;; This file incorporates work covered by the following copyright and  
+;; permission notice:
+;;
+;;   Copyright © 2009, 2010 Göran Weinholt <goran@weinholt.se>
+;;
+;;   Permission is hereby granted, free of charge, to any person obtaining a
+;;   copy of this software and associated documentation files (the "Software"),
+;;   to deal in the Software without restriction, including without limitation
+;;   the rights to use, copy, modify, merge, publish, distribute, sublicense,
+;;   and/or sell copies of the Software, and to permit persons to whom the
+;;   Software is furnished to do so, subject to the following conditions:
+;;
+;;   The above copyright notice and this permission notice shall be included in
+;;   all copies or substantial portions of the Software.
+;;
+;;   THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
+;;   IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
+;;   FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL
+;;   THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
+;;   LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
+;;   FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
+;;   DEALINGS IN THE SOFTWARE.
+
+;; RFC 4648 Base-N Encodings
+
+(define-module (pict base64)
+  #:export (base64-encode
+            base64-decode
+            base64-alphabet
+            base64url-alphabet
+            get-delimited-base64
+            put-delimited-base64)
+  #:use-module (rnrs)
+  #:use-module ((srfi srfi-13)
+                #:select (string-index
+                          string-prefix? string-suffix?
+                          string-concatenate string-trim-both)))
+
+
+(define-syntax define-alias
+  (syntax-rules ()
+    ((_ new old)
+     (define-syntax new (identifier-syntax old)))))
+
+;; Force the use of Guile's own primitives to avoid the overhead of its 'fx'
+;; procedures.
+
+(define-alias fxbit-field bitwise-bit-field)
+(define-alias fxarithmetic-shift ash)
+(define-alias fxarithmetic-shift-left ash)
+(define-alias fxand logand)
+(define-alias fxior logior)
+(define-alias fxxor logxor)
+
+(define base64-alphabet
+  "ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789+/")
+
+(define base64url-alphabet
+  "ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789-_")
+
+(define base64-encode
+  (case-lambda
+    ;; Simple interface. Returns a string containing the canonical
+    ;; base64 representation of the given bytevector.
+    ((bv)
+     (base64-encode bv 0 (bytevector-length bv) #f #f base64-alphabet #f))
+    ((bv start)
+     (base64-encode bv start (bytevector-length bv) #f #f base64-alphabet #f))
+    ((bv start end)
+     (base64-encode bv start end #f #f base64-alphabet #f))
+    ((bv start end line-length)
+     (base64-encode bv start end line-length #f base64-alphabet #f))
+    ((bv start end line-length no-padding)
+     (base64-encode bv start end line-length no-padding base64-alphabet #f))
+    ((bv start end line-length no-padding alphabet)
+     (base64-encode bv start end line-length no-padding alphabet #f))
+    ;; Base64 encodes the bytes [start,end[ in the given bytevector.
+    ;; Lines are limited to line-length characters (unless #f),
+    ;; which must be a multiple of four. To omit the padding
+    ;; characters (#\=) set no-padding to a true value. If port is
+    ;; #f, returns a string.
+    ((bv start end line-length no-padding alphabet port)
+     (assert (or (not line-length) (zero? (mod line-length 4))))
+     (let-values (((p extract) (if port
+                                   (values port (lambda () (values)))
+                                   (open-string-output-port))))
+       (letrec ((put (if line-length
+                         (let ((chars 0))
+                           (lambda (p c)
+                             (when (fx=? chars line-length)
+                               (set! chars 0)
+                               (put-char p #\linefeed))
+                             (set! chars (fx+ chars 1))
+                             (put-char p c)))
+                         put-char)))
+         (let lp ((i start))
+           (cond ((= i end))
+                 ((<= (+ i 3) end)
+                  (let ((x (bytevector-uint-ref bv i (endianness big) 3)))
+                    (put p (string-ref alphabet (fxbit-field x 18 24)))
+                    (put p (string-ref alphabet (fxbit-field x 12 18)))
+                    (put p (string-ref alphabet (fxbit-field x 6 12)))
+                    (put p (string-ref alphabet (fxbit-field x 0 6)))
+                    (lp (+ i 3))))
+                 ((<= (+ i 2) end)
+                  (let ((x (fxarithmetic-shift-left (bytevector-u16-ref bv i (endianness big)) 8)))
+                    (put p (string-ref alphabet (fxbit-field x 18 24)))
+                    (put p (string-ref alphabet (fxbit-field x 12 18)))
+                    (put p (string-ref alphabet (fxbit-field x 6 12)))
+                    (unless no-padding
+                      (put p #\=))))
+                 (else
+                  (let ((x (fxarithmetic-shift-left (bytevector-u8-ref bv i) 16)))
+                    (put p (string-ref alphabet (fxbit-field x 18 24)))
+                    (put p (string-ref alphabet (fxbit-field x 12 18)))
+                    (unless no-padding
+                      (put p #\=)
+                      (put p #\=)))))))
+       (extract)))))
+
+  ;; Decodes a base64 string. The string must contain only pure
+  ;; unpadded base64 data.
+  
+(define base64-decode
+  (case-lambda
+    ((str)
+     (base64-decode str base64-alphabet #f))
+    ((str alphabet)
+     (base64-decode str alphabet #f))
+    ((str alphabet port)
+     (unless (zero? (mod (string-length str) 4))
+       (error 'base64-decode
+              "input string must be a multiple of four characters"))
+     (let-values (((p extract) (if port
+                                   (values port (lambda () (values)))
+                                   (open-bytevector-output-port))))
+       (do ((i 0 (+ i 4)))
+           ((= i (string-length str))
+            (extract))
+         (let ((c1 (string-ref str i))
+               (c2 (string-ref str (+ i 1)))
+               (c3 (string-ref str (+ i 2)))
+               (c4 (string-ref str (+ i 3))))
+           ;; TODO: be more clever than string-index
+           (let ((i1 (string-index alphabet c1))
+                 (i2 (string-index alphabet c2))
+                 (i3 (string-index alphabet c3))
+                 (i4 (string-index alphabet c4)))
+             (cond ((and i1 i2 i3 i4)
+                    (let ((x (fxior (fxarithmetic-shift-left i1 18)
+                                    (fxarithmetic-shift-left i2 12)
+                                    (fxarithmetic-shift-left i3 6)
+                                    i4)))
+                      (put-u8 p (fxbit-field x 16 24))
+                      (put-u8 p (fxbit-field x 8 16))
+                      (put-u8 p (fxbit-field x 0 8))))
+                   ((and i1 i2 i3 (char=? c4 #\=)
+                         (= i (- (string-length str) 4)))
+                    (let ((x (fxior (fxarithmetic-shift-left i1 18)
+                                    (fxarithmetic-shift-left i2 12)
+                                    (fxarithmetic-shift-left i3 6))))
+                      (put-u8 p (fxbit-field x 16 24))
+                      (put-u8 p (fxbit-field x 8 16))))
+                   ((and i1 i2 (char=? c3 #\=) (char=? c4 #\=)
+                         (= i (- (string-length str) 4)))
+                    (let ((x (fxior (fxarithmetic-shift-left i1 18)
+                                    (fxarithmetic-shift-left i2 12))))
+                      (put-u8 p (fxbit-field x 16 24))))
+                   (else
+                    (error 'base64-decode "invalid input"
+                           (list c1 c2 c3 c4)))))))))))
+
+(define (get-line-comp f port)
+  (if (port-eof? port)
+      (eof-object)
+      (f (get-line port))))
+
+  ;; Reads the common -----BEGIN/END type----- delimited format from
+  ;; the given port. Returns two values: a string with the type and a
+  ;; bytevector containing the base64 decoded data. The second value
+  ;; is the eof object if there is an eof before the BEGIN delimiter.
+  
+(define (get-delimited-base64 port)
+  (define (get-first-data-line port)
+    ;; Some MIME data has header fields in the same format as mail
+    ;; or http. These are ignored.
+    (let ((line (get-line-comp string-trim-both port)))
+      (cond ((eof-object? line) line)
+            ((string-index line #\:)
+             (let lp ()                           ;read until empty line
+               (let ((line (get-line-comp string-trim-both port)))
+                 (if (string=? line "")
+                     (get-line-comp string-trim-both port)
+                     (lp)))))
+            (else line))))
+  (let ((line (get-line-comp string-trim-both port)))
+    (cond ((eof-object? line)
+           (values "" (eof-object)))
+          ((string=? line "")
+           (get-delimited-base64 port))
+          ((and (string-prefix? "-----BEGIN " line)
+                (string-suffix? "-----" line))
+           (let* ((type (substring line 11 (- (string-length line) 5)))
+                  (endline (string-append "-----END " type "-----")))
+             (let-values (((outp extract) (open-bytevector-output-port)))
+               (let lp ((line (get-first-data-line port)))
+                 (cond ((eof-object? line)
+                        (error 'get-delimited-base64
+                               "unexpected end of file"))
+                       ((string-prefix? "-" line)
+                        (unless (string=? line endline)
+                          (error 'get-delimited-base64
+                                 "bad end delimiter" type line))
+                        (values type (extract)))
+                       (else
+                        (unless (and (= (string-length line) 5)
+                                     (string-prefix? "=" line)) ;Skip Radix-64 checksum
+                          (base64-decode line base64-alphabet outp))
+                        (lp (get-line-comp string-trim-both port))))))))
+          (else     ;skip garbage (like in openssl x509 -in foo -text output).
+           (get-delimited-base64 port)))))
+
+(define put-delimited-base64
+  (case-lambda
+    ((port type bv line-length)
+     (display (string-append "-----BEGIN " type "-----\n") port)
+     (base64-encode bv 0 (bytevector-length bv)
+                    line-length #f base64-alphabet port)
+     (display (string-append "\n-----END " type "-----\n") port))
+    ((port type bv)
+     (put-delimited-base64 port type bv 76))))