dnl weipub - Teeny tiny activitypub thing
dnl Copyright © 2022 Ricardo Wurmus <rekado@elephly.net>
dnl
dnl This program is free software: you can redistribute it and/or
dnl modify it under the terms of the GNU Affero General Public License
dnl as published by the Free Software Foundation, either version 3 of
dnl the License, or (at your option) any later version.
dnl
dnl This program is distributed in the hope that it will be useful, but
dnl WITHOUT ANY WARRANTY; without even the implied warranty of
dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
dnl Affero General Public License for more details.
dnl
dnl You should have received a copy of the GNU Affero General Public
dnl License along with this program.  If not, see
dnl <http://www.gnu.org/licenses/>.
dnl -*- Autoconf -*-

AC_INIT([weipub],
  [0.0.1],
  [enquiries+weipub@elephly.net], [weipub],
  [https://git.elephly.net/software/weipub.git/])
AC_CONFIG_AUX_DIR([build-aux])
AM_INIT_AUTOMAKE([color-tests -Wall -Wno-portability foreign])
AM_SILENT_RULES([yes])

GUILE_PKG([3.0])
GUILE_PROGS

if test "x$GUILD" = "x"; then
   AC_MSG_ERROR(['guild' binary not found; please check your Guile installation.])
fi

dnl Installation directories for .scm and .go files.
guilemoduledir="${datarootdir}/guile/site/$GUILE_EFFECTIVE_VERSION"
guileobjectdir="${libdir}/guile/$GUILE_EFFECTIVE_VERSION/site-ccache"
AC_SUBST([guilemoduledir])
AC_SUBST([guileobjectdir])

GUILE_MODULE_REQUIRED(json)
GUILE_MODULE_REQUIRED(sqlite3)
GUILE_MODULE_REQUIRED(gcrypt hash)
GUILE_MODULE_REQUIRED(config)
GUILE_MODULE_CHECK(guile_config_too_old,(config api),(argument (name 'foo) (optional? 'old)),supports `optional?' field in argument definition)
if test "x$guile_config_too_old" = "xyes"; then
   AC_MSG_ERROR([Guile Config needs to be version 0.5.0 or higher.])
fi

AC_CONFIG_FILES([Makefile weipub/config.scm])
AC_CONFIG_FILES([pre-inst-env], [chmod +x pre-inst-env])

AC_OUTPUT