;;; The Inevitable Game
;;; Copyright © 2018, 2021 Ricardo Wurmus <rekado@elephly.net>
;;;
;;; This program is free software: you can redistribute it and/or
;;; modify it under the terms of the GNU General Public License as
;;; published by the Free Software Foundation, either version 3 of the
;;; License, or (at your option) any later version.
;;;
;;; This program is distributed in the hope that it will be useful,
;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
;;; General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with this program.  If not, see
;;; <http://www.gnu.org/licenses/>.

(define-module (scenes intro)
  #:use-module (chickadee audio)
  #:use-module (chickadee math rect)
  #:use-module (chickadee math vector)
  #:use-module ((chickadee graphics color) #:select (make-color))
  #:use-module (chickadee graphics font)
  #:use-module (chickadee graphics texture)
  #:use-module (chickadee scripting)
  #:use-module (engine assets)
  #:use-module (engine node)
  #:use-module (engine node-2d)
  #:use-module (engine scene)
  #:use-module (engine shell)
  #:use-module (config)
  #:use-module (scenes game)
  #:use-module (oop goops)
  #:export (intro))

(define-class <intro> (<scene>))

(define-asset game-font
  (load-bitmap-font "assets/fonts/good_neighbors_starling.xml"))

(define-asset intro-bg (load-image "assets/images/intro-bg.png"))

(define texts
  '("\
The void has been suspended for
a little while. You exist now."
    "\
Confusion gives way to a brief
burst of consciousness.
Here you are. What now?"
    "\
The haze clears and you can see
that you are here now. You did not
ask for this."
    "\
You rise from deepest waters and
take your first breath. You wonder:
will this last?"
    "\
History yields to the present.
The present crumbles underfoot.
You better move."
    "\
A leaf has turned.
The sunshine warms and blinds.
The leaf begins to dry."))

(set! *random-state* (random-state-from-platform))

(define-method (populate (intro <intro>))
  (cons
   (let ((text "Press enter to start.")
         (font game-font))
     (make <label>
       #:name 'press-enter
       #:font font
       #:text text
       #:position
       (let ((width (font-line-width (asset-ref font) text)))
         (vec2 (- (/ %width 2)
                  (/ width 2))
               30.0))))
   (let* ((text (list-ref texts (random (length texts))))
          (parts (string-split text #\newline)))
     (map (lambda (part i)
            (make <label>
              #:name 'welcome
              #:font game-font
              #:text part
              #:position (vec2 (- (/ %width 2)
                                  (/ (font-line-width (asset-ref game-font) part) 2))
                               (- 120.0 (* 15 i)))))
          parts (iota (length parts))))))

(define-method (on-key-press (intro <intro>) key mods repeat?)
  (when (eq? key 'return)
    (let ((fade (child-ref (parent intro) 'fade-all)))
      (script
       (tween 60 0.0 1.0
              (lambda (alpha)
                (set! (color fade)
                      (make-color 0 0 0 alpha))))
       (switch-scene (root-node)
                     (game))))))

(define (intro)
  (audio-play (load-audio "assets/music/intro.ogg"))
  (let ((container (make <node-2d>
                     #:children
                     (list
                      (make <sprite>
                        #:name 'bg
                        #:texture (asset-ref intro-bg))
                      (make <intro>)
                      (make <filled-rect>
                        #:name 'fade-all
                        #:region (make-rect 0.0 0.0 %width %height)
                        #:color (make-color 1 1 1 1.0))))))
    ;; Fade in
    (with-agenda
     (agenda container)
     (script
      (tween 240 1.0 0.0
             (lambda (alpha)
               (set! (color (child-ref container 'fade-all))
                     (make-color 1 1 1 alpha))))))
    container))