remove warnings, reordering
[software/python-on-guile.git] / modules / acinclude.m4
1 ## Autoconf macros for working with Guile.
2 ##
3 ## Copyright (C) 1998,2001, 2006, 2010, 2012, 2013, 2014 Free Software Foundation, Inc.
4 ##
5 ## This library is free software; you can redistribute it and/or
6 ## modify it under the terms of the GNU Lesser General Public License
7 ## as published by the Free Software Foundation; either version 3 of
8 ## the License, or (at your option) any later version.
9 ##
10 ## This library is distributed in the hope that it will be useful,
11 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
12 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
13 ## Lesser General Public License for more details.
14 ##
15 ## You should have received a copy of the GNU Lesser General Public
16 ## License along with this library; if not, write to the Free Software
17 ## Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
18 ## 02110-1301 USA
19
20 # serial 10
21
22 ## Index
23 ## -----
24 ##
25 ## GUILE_PKG -- find Guile development files
26 ## GUILE_PROGS -- set paths to Guile interpreter, config and tool programs
27 ## GUILE_FLAGS -- set flags for compiling and linking with Guile
28 ## GUILE_SITE_DIR -- find path to Guile "site" directories
29 ## GUILE_CHECK -- evaluate Guile Scheme code and capture the return value
30 ## GUILE_MODULE_CHECK -- check feature of a Guile Scheme module
31 ## GUILE_MODULE_AVAILABLE -- check availability of a Guile Scheme module
32 ## GUILE_MODULE_REQUIRED -- fail if a Guile Scheme module is unavailable
33 ## GUILE_MODULE_EXPORTS -- check if a module exports a variable
34 ## GUILE_MODULE_REQUIRED_EXPORT -- fail if a module doesn't export a variable
35
36 ## Code
37 ## ----
38
39 ## NOTE: Comments preceding an AC_DEFUN (starting from "Usage:") are massaged
40 ## into doc/ref/autoconf-macros.texi (see Makefile.am in that directory).
41
42 # GUILE_PKG -- find Guile development files
43 #
44 # Usage: GUILE_PKG([VERSIONS])
45 #
46 # This macro runs the @code{pkg-config} tool to find development files
47 # for an available version of Guile.
48 #
49 # By default, this macro will search for the latest stable version of
50 # Guile (e.g. 2.2), falling back to the previous stable version
51 # (e.g. 2.0) if it is available. If no guile-@var{VERSION}.pc file is
52 # found, an error is signalled. The found version is stored in
53 # @var{GUILE_EFFECTIVE_VERSION}.
54 #
55 # If @code{GUILE_PROGS} was already invoked, this macro ensures that the
56 # development files have the same effective version as the Guile
57 # program.
58 #
59 # @var{GUILE_EFFECTIVE_VERSION} is marked for substitution, as by
60 # @code{AC_SUBST}.
61 #
62 AC_DEFUN([GUILE_PKG],
63 [PKG_PROG_PKG_CONFIG
64 _guile_versions_to_search="m4_default([$1], [2.2 2.0 1.8])"
65 if test -n "$GUILE_EFFECTIVE_VERSION"; then
66 _guile_tmp=""
67 for v in $_guile_versions_to_search; do
68 if test "$v" = "$GUILE_EFFECTIVE_VERSION"; then
69 _guile_tmp=$v
70 fi
71 done
72 if test -z "$_guile_tmp"; then
73 AC_MSG_FAILURE([searching for guile development files for versions $_guile_versions_to_search, but previously found $GUILE version $GUILE_EFFECTIVE_VERSION])
74 fi
75 _guile_versions_to_search=$GUILE_EFFECTIVE_VERSION
76 fi
77 GUILE_EFFECTIVE_VERSION=""
78 _guile_errors=""
79 for v in $_guile_versions_to_search; do
80 if test -z "$GUILE_EFFECTIVE_VERSION"; then
81 AC_MSG_NOTICE([checking for guile $v])
82 PKG_CHECK_EXISTS([guile-$v], [GUILE_EFFECTIVE_VERSION=$v], [])
83 fi
84 done
85
86 if test -z "$GUILE_EFFECTIVE_VERSION"; then
87 AC_MSG_ERROR([
88 No Guile development packages were found.
89
90 Please verify that you have Guile installed. If you installed Guile
91 from a binary distribution, please verify that you have also installed
92 the development packages. If you installed it yourself, you might need
93 to adjust your PKG_CONFIG_PATH; see the pkg-config man page for more.
94 ])
95 fi
96 AC_MSG_NOTICE([found guile $GUILE_EFFECTIVE_VERSION])
97 AC_SUBST([GUILE_EFFECTIVE_VERSION])
98 ])
99
100 # GUILE_FLAGS -- set flags for compiling and linking with Guile
101 #
102 # Usage: GUILE_FLAGS
103 #
104 # This macro runs the @code{pkg-config} tool to find out how to compile
105 # and link programs against Guile. It sets four variables:
106 # @var{GUILE_CFLAGS}, @var{GUILE_LDFLAGS}, @var{GUILE_LIBS}, and
107 # @var{GUILE_LTLIBS}.
108 #
109 # @var{GUILE_CFLAGS}: flags to pass to a C or C++ compiler to build code that
110 # uses Guile header files. This is almost always just one or more @code{-I}
111 # flags.
112 #
113 # @var{GUILE_LDFLAGS}: flags to pass to the compiler to link a program
114 # against Guile. This includes @code{-lguile-@var{VERSION}} for the
115 # Guile library itself, and may also include one or more @code{-L} flag
116 # to tell the compiler where to find the libraries. But it does not
117 # include flags that influence the program's runtime search path for
118 # libraries, and will therefore lead to a program that fails to start,
119 # unless all necessary libraries are installed in a standard location
120 # such as @file{/usr/lib}.
121 #
122 # @var{GUILE_LIBS} and @var{GUILE_LTLIBS}: flags to pass to the compiler or to
123 # libtool, respectively, to link a program against Guile. It includes flags
124 # that augment the program's runtime search path for libraries, so that shared
125 # libraries will be found at the location where they were during linking, even
126 # in non-standard locations. @var{GUILE_LIBS} is to be used when linking the
127 # program directly with the compiler, whereas @var{GUILE_LTLIBS} is to be used
128 # when linking the program is done through libtool.
129 #
130 # The variables are marked for substitution, as by @code{AC_SUBST}.
131 #
132 AC_DEFUN([GUILE_FLAGS],
133 [AC_REQUIRE([GUILE_PKG])
134 PKG_CHECK_MODULES(GUILE, [guile-$GUILE_EFFECTIVE_VERSION])
135
136 dnl GUILE_CFLAGS and GUILE_LIBS are already defined and AC_SUBST'd by
137 dnl PKG_CHECK_MODULES. But GUILE_LIBS to pkg-config is GUILE_LDFLAGS
138 dnl to us.
139
140 GUILE_LDFLAGS=$GUILE_LIBS
141
142 dnl Determine the platform dependent parameters needed to use rpath.
143 dnl AC_LIB_LINKFLAGS_FROM_LIBS is defined in gnulib/m4/lib-link.m4 and needs
144 dnl the file gnulib/build-aux/config.rpath.
145 AC_LIB_LINKFLAGS_FROM_LIBS([GUILE_LIBS], [$GUILE_LDFLAGS], [])
146 GUILE_LIBS="$GUILE_LDFLAGS $GUILE_LIBS"
147 AC_LIB_LINKFLAGS_FROM_LIBS([GUILE_LTLIBS], [$GUILE_LDFLAGS], [yes])
148 GUILE_LTLIBS="$GUILE_LDFLAGS $GUILE_LTLIBS"
149
150 AC_SUBST([GUILE_EFFECTIVE_VERSION])
151 AC_SUBST([GUILE_CFLAGS])
152 AC_SUBST([GUILE_LDFLAGS])
153 AC_SUBST([GUILE_LIBS])
154 AC_SUBST([GUILE_LTLIBS])
155 ])
156
157 # GUILE_SITE_DIR -- find path to Guile site directories
158 #
159 # Usage: GUILE_SITE_DIR
160 #
161 # This looks for Guile's "site" directories. The variable @var{GUILE_SITE} will
162 # be set to Guile's "site" directory for Scheme source files (usually something
163 # like PREFIX/share/guile/site). @var{GUILE_SITE_CCACHE} will be set to the
164 # directory for compiled Scheme files also known as @code{.go} files
165 # (usually something like
166 # PREFIX/lib/guile/@var{GUILE_EFFECTIVE_VERSION}/site-ccache).
167 # @var{GUILE_EXTENSION} will be set to the directory for compiled C extensions
168 # (usually something like
169 # PREFIX/lib/guile/@var{GUILE_EFFECTIVE_VERSION}/extensions). The latter two
170 # are set to blank if the particular version of Guile does not support
171 # them. Note that this macro will run the macros @code{GUILE_PKG} and
172 # @code{GUILE_PROGS} if they have not already been run.
173 #
174 # The variables are marked for substitution, as by @code{AC_SUBST}.
175 #
176 AC_DEFUN([GUILE_SITE_DIR],
177 [AC_REQUIRE([GUILE_PKG])
178 AC_REQUIRE([GUILE_PROGS])
179 AC_MSG_CHECKING(for Guile site directory)
180 GUILE_SITE=`$PKG_CONFIG --print-errors --variable=sitedir guile-$GUILE_EFFECTIVE_VERSION`
181 AC_MSG_RESULT($GUILE_SITE)
182 if test "$GUILE_SITE" = ""; then
183 AC_MSG_FAILURE(sitedir not found)
184 fi
185 AC_SUBST(GUILE_SITE)
186 AC_MSG_CHECKING([for Guile site-ccache directory using pkgconfig])
187 GUILE_SITE_CCACHE=`$PKG_CONFIG --variable=siteccachedir guile-$GUILE_EFFECTIVE_VERSION`
188 if test "$GUILE_SITE_CCACHE" = ""; then
189 AC_MSG_RESULT(no)
190 AC_MSG_CHECKING([for Guile site-ccache directory using interpreter])
191 GUILE_SITE_CCACHE=`$GUILE -c "(display (if (defined? '%site-ccache-dir) (%site-ccache-dir) \"\"))"`
192 if test $? != "0" -o "$GUILE_SITE_CCACHE" = ""; then
193 AC_MSG_RESULT(no)
194 GUILE_SITE_CCACHE=""
195 AC_MSG_WARN([siteccachedir not found])
196 fi
197 fi
198 AC_MSG_RESULT($GUILE_SITE_CCACHE)
199 AC_SUBST([GUILE_SITE_CCACHE])
200 AC_MSG_CHECKING(for Guile extensions directory)
201 GUILE_EXTENSION=`$PKG_CONFIG --print-errors --variable=extensiondir guile-$GUILE_EFFECTIVE_VERSION`
202 AC_MSG_RESULT($GUILE_EXTENSION)
203 if test "$GUILE_EXTENSION" = ""; then
204 GUILE_EXTENSION=""
205 AC_MSG_WARN(extensiondir not found)
206 fi
207 AC_SUBST(GUILE_EXTENSION)
208 ])
209
210 # GUILE_PROGS -- set paths to Guile interpreter, config and tool programs
211 #
212 # Usage: GUILE_PROGS([VERSION])
213 #
214 # This macro looks for programs @code{guile} and @code{guild}, setting
215 # variables @var{GUILE} and @var{GUILD} to their paths, respectively.
216 # The macro will attempt to find @code{guile} with the suffix of
217 # @code{-X.Y}, followed by looking for it with the suffix @code{X.Y}, and
218 # then fall back to looking for @code{guile} with no suffix. If
219 # @code{guile} is still not found, signal an error. The suffix, if any,
220 # that was required to find @code{guile} will be used for @code{guild}
221 # as well.
222 #
223 # By default, this macro will search for the latest stable version of
224 # Guile (e.g. 2.2). x.y or x.y.z versions can be specified. If an older
225 # version is found, the macro will signal an error.
226 #
227 # The effective version of the found @code{guile} is set to
228 # @var{GUILE_EFFECTIVE_VERSION}. This macro ensures that the effective
229 # version is compatible with the result of a previous invocation of
230 # @code{GUILE_FLAGS}, if any.
231 #
232 # As a legacy interface, it also looks for @code{guile-config} and
233 # @code{guile-tools}, setting @var{GUILE_CONFIG} and @var{GUILE_TOOLS}.
234 #
235 # The variables are marked for substitution, as by @code{AC_SUBST}.
236 #
237 AC_DEFUN([GUILE_PROGS],
238 [_guile_required_version="m4_default([$1], [$GUILE_EFFECTIVE_VERSION])"
239 if test -z "$_guile_required_version"; then
240 _guile_required_version=2.2
241 fi
242
243 _guile_candidates=guile
244 _tmp=
245 for v in `echo "$_guile_required_version" | tr . ' '`; do
246 if test -n "$_tmp"; then _tmp=$_tmp.; fi
247 _tmp=$_tmp$v
248 _guile_candidates="guile-$_tmp guile$_tmp $_guile_candidates"
249 done
250
251 AC_PATH_PROGS(GUILE,[$_guile_candidates])
252 if test -z "$GUILE"; then
253 AC_MSG_ERROR([guile required but not found])
254 fi
255
256 _guile_suffix=`echo "$GUILE" | sed -e 's,^.*/guile\(.*\)$,\1,'`
257 _guile_effective_version=`$GUILE -c "(display (effective-version))"`
258 if test -z "$GUILE_EFFECTIVE_VERSION"; then
259 GUILE_EFFECTIVE_VERSION=$_guile_effective_version
260 elif test "$GUILE_EFFECTIVE_VERSION" != "$_guile_effective_version"; then
261 AC_MSG_ERROR([found development files for Guile $GUILE_EFFECTIVE_VERSION, but $GUILE has effective version $_guile_effective_version])
262 fi
263
264 _guile_major_version=`$GUILE -c "(display (major-version))"`
265 _guile_minor_version=`$GUILE -c "(display (minor-version))"`
266 _guile_micro_version=`$GUILE -c "(display (micro-version))"`
267 _guile_prog_version="$_guile_major_version.$_guile_minor_version.$_guile_micro_version"
268
269 AC_MSG_CHECKING([for Guile version >= $_guile_required_version])
270 _major_version=`echo $_guile_required_version | cut -d . -f 1`
271 _minor_version=`echo $_guile_required_version | cut -d . -f 2`
272 _micro_version=`echo $_guile_required_version | cut -d . -f 3`
273 if test "$_guile_major_version" -gt "$_major_version"; then
274 true
275 elif test "$_guile_major_version" -eq "$_major_version"; then
276 if test "$_guile_minor_version" -gt "$_minor_version"; then
277 true
278 elif test "$_guile_minor_version" -eq "$_minor_version"; then
279 if test -n "$_micro_version"; then
280 if test "$_guile_micro_version" -lt "$_micro_version"; then
281 AC_MSG_ERROR([Guile $_guile_required_version required, but $_guile_prog_version found])
282 fi
283 fi
284 elif test "$GUILE_EFFECTIVE_VERSION" = "$_major_version.$_minor_version" -a -z "$_micro_version"; then
285 # Allow prereleases that have the right effective version.
286 true
287 else
288 as_fn_error $? "Guile $_guile_required_version required, but $_guile_prog_version found" "$LINENO" 5
289 fi
290 elif test "$GUILE_EFFECTIVE_VERSION" = "$_major_version.$_minor_version" -a -z "$_micro_version"; then
291 # Allow prereleases that have the right effective version.
292 true
293 else
294 AC_MSG_ERROR([Guile $_guile_required_version required, but $_guile_prog_version found])
295 fi
296 AC_MSG_RESULT([$_guile_prog_version])
297
298 AC_PATH_PROG(GUILD,[guild$_guile_suffix])
299 AC_SUBST(GUILD)
300
301 AC_PATH_PROG(GUILE_CONFIG,[guile-config$_guile_suffix])
302 AC_SUBST(GUILE_CONFIG)
303 if test -n "$GUILD"; then
304 GUILE_TOOLS=$GUILD
305 else
306 AC_PATH_PROG(GUILE_TOOLS,[guile-tools$_guile_suffix])
307 fi
308 AC_SUBST(GUILE_TOOLS)
309 ])
310
311 # GUILE_CHECK -- evaluate Guile Scheme code and capture the return value
312 #
313 # Usage: GUILE_CHECK_RETVAL(var,check)
314 #
315 # @var{var} is a shell variable name to be set to the return value.
316 # @var{check} is a Guile Scheme expression, evaluated with "$GUILE -c", and
317 # returning either 0 or non-#f to indicate the check passed.
318 # Non-0 number or #f indicates failure.
319 # Avoid using the character "#" since that confuses autoconf.
320 #
321 AC_DEFUN([GUILE_CHECK],
322 [AC_REQUIRE([GUILE_PROGS])
323 $GUILE -c "$2" > /dev/null 2>&1
324 $1=$?
325 ])
326
327 # GUILE_MODULE_CHECK -- check feature of a Guile Scheme module
328 #
329 # Usage: GUILE_MODULE_CHECK(var,module,featuretest,description)
330 #
331 # @var{var} is a shell variable name to be set to "yes" or "no".
332 # @var{module} is a list of symbols, like: (ice-9 common-list).
333 # @var{featuretest} is an expression acceptable to GUILE_CHECK, q.v.
334 # @var{description} is a present-tense verb phrase (passed to AC_MSG_CHECKING).
335 #
336 AC_DEFUN([GUILE_MODULE_CHECK],
337 [AC_MSG_CHECKING([if $2 $4])
338 GUILE_CHECK($1,(use-modules $2) (exit ((lambda () $3))))
339 if test "$$1" = "0" ; then $1=yes ; else $1=no ; fi
340 AC_MSG_RESULT($$1)
341 ])
342
343 # GUILE_MODULE_AVAILABLE -- check availability of a Guile Scheme module
344 #
345 # Usage: GUILE_MODULE_AVAILABLE(var,module)
346 #
347 # @var{var} is a shell variable name to be set to "yes" or "no".
348 # @var{module} is a list of symbols, like: (ice-9 common-list).
349 #
350 AC_DEFUN([GUILE_MODULE_AVAILABLE],
351 [GUILE_MODULE_CHECK($1,$2,0,is available)
352 ])
353
354 # GUILE_MODULE_REQUIRED -- fail if a Guile Scheme module is unavailable
355 #
356 # Usage: GUILE_MODULE_REQUIRED(symlist)
357 #
358 # @var{symlist} is a list of symbols, WITHOUT surrounding parens,
359 # like: ice-9 common-list.
360 #
361 AC_DEFUN([GUILE_MODULE_REQUIRED],
362 [GUILE_MODULE_AVAILABLE(ac_guile_module_required, ($1))
363 if test "$ac_guile_module_required" = "no" ; then
364 AC_MSG_ERROR([required guile module not found: ($1)])
365 fi
366 ])
367
368 # GUILE_MODULE_EXPORTS -- check if a module exports a variable
369 #
370 # Usage: GUILE_MODULE_EXPORTS(var,module,modvar)
371 #
372 # @var{var} is a shell variable to be set to "yes" or "no".
373 # @var{module} is a list of symbols, like: (ice-9 common-list).
374 # @var{modvar} is the Guile Scheme variable to check.
375 #
376 AC_DEFUN([GUILE_MODULE_EXPORTS],
377 [GUILE_MODULE_CHECK($1,$2,$3,exports `$3')
378 ])
379
380 # GUILE_MODULE_REQUIRED_EXPORT -- fail if a module doesn't export a variable
381 #
382 # Usage: GUILE_MODULE_REQUIRED_EXPORT(module,modvar)
383 #
384 # @var{module} is a list of symbols, like: (ice-9 common-list).
385 # @var{modvar} is the Guile Scheme variable to check.
386 #
387 AC_DEFUN([GUILE_MODULE_REQUIRED_EXPORT],
388 [GUILE_MODULE_EXPORTS(guile_module_required_export,$1,$2)
389 if test "$guile_module_required_export" = "no" ; then
390 AC_MSG_ERROR([module $1 does not export $2; required])
391 fi
392 ])
393
394 ## guile.m4 ends here