messages: Implement search with mu.
[software/mumi.git] / mumi / messages.scm
1 ;;; mumi -- Mediocre, uh, mail interface
2 ;;; Copyright © 2017, 2018, 2019, 2020 Ricardo Wurmus <rekado@elephly.net>
3 ;;; Copyright © 2018, 2019 Arun Isaac <arunisaac@systemreboot.net>
4 ;;;
5 ;;; This program is free software: you can redistribute it and/or
6 ;;; modify it under the terms of the GNU Affero General Public License
7 ;;; as published by the Free Software Foundation, either version 3 of
8 ;;; the License, or (at your option) any later version.
9 ;;;
10 ;;; This program is distributed in the hope that it will be useful,
11 ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
12 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
13 ;;; Affero General Public License for more details.
14 ;;;
15 ;;; You should have received a copy of the GNU Affero General Public
16 ;;; License along with this program. If not, see
17 ;;; <http://www.gnu.org/licenses/>.
18
19 (define-module (mumi messages)
20 #:use-module (srfi srfi-1)
21 #:use-module (srfi srfi-19)
22 #:use-module (srfi srfi-26)
23 #:use-module (ice-9 optargs)
24 #:use-module (ice-9 regex)
25 #:use-module (ice-9 match)
26 #:use-module (ice-9 textual-ports)
27 #:use-module (ice-9 binary-ports)
28 #:use-module (debbugs cache)
29 #:use-module (debbugs soap)
30 #:use-module (debbugs operations)
31 #:use-module (debbugs bug)
32 #:use-module (email email)
33 #:use-module (mumi config)
34 #:use-module ((mumi bugs) #:prefix db:)
35 #:use-module (mumimu)
36 #:export (search-bugs
37 fetch-bug
38 recent-bugs
39 easy-bugs
40 bugs-by-severity
41
42 download-message
43
44 multipart-message?
45 extract-attachment))
46
47 (define (status-with-cache ids)
48 "Invoke GET-STATUS, but only on those IDS that have not been cached
49 yet. Return new results alongside cached results."
50 (let* ((cached (filter-map cached? ids))
51 (uncached-ids (lset-difference eq?
52 ids
53 (map bug-num cached)))
54 (new (soap-invoke* (%config 'debbugs) get-status uncached-ids)))
55 ;; Cache new things
56 (map (lambda (bug) (cache! (bug-num bug) bug)) new)
57 ;; Return everything from cache
58 (sort (append cached new) (lambda (a b) (< (bug-num a) (bug-num b))))))
59
60 (define-public (extract-name address)
61 (or (assoc-ref address 'name)
62 (and=> (assoc-ref address 'address)
63 (lambda (address)
64 (string-take address (string-index address #\@))))
65 "Somebody"))
66
67 (define-public (extract-email address)
68 (assoc-ref address 'address))
69
70 (define (header message key)
71 (assoc-ref (email-headers message) key))
72
73 (define-public (sender message)
74 (first (header message 'from)))
75
76 (define-public sender-email
77 (compose extract-email sender))
78
79 (define-public (sender-name message)
80 (extract-name (sender message)))
81
82 (define-public (date message)
83 (header message 'date))
84
85 (define-public (subject message)
86 (or (header message 'subject) "(no subject)"))
87
88 (define-public (message-id message)
89 (header message 'message-id))
90
91 (define-public (participants messages)
92 "Return a list of unique senders in the conversion."
93 (apply lset-adjoin (lambda (a b)
94 (string= (extract-email a)
95 (extract-email b)))
96 '() (map sender messages)))
97
98 (define-public (recipients message)
99 "Return a list of recipient email addresses for the given MESSAGE."
100 (let ((headers (email-headers message)))
101 (filter-map (match-lambda
102 (((or 'cc 'bcc 'to) val) val)
103 (_ #f)) headers)))
104
105 (define-public (closing? message id)
106 "Is this MESSAGE closing this bug ID?"
107 (let ((done (string-append (number->string id)
108 "-done")))
109 (string= (header message 'x-debbugs-envelope-to) done)))
110
111 (define-public (bot? address)
112 (string= "help-debbugs@gnu.org" address))
113
114 (define-public (internal-message? message)
115 (bot? (sender-email message)))
116
117 \f
118 (define (multipart-message? message)
119 (eq? (assoc-ref (header message 'content-type)
120 'type)
121 'multipart))
122
123 (define (extract-attachment id msg-num path)
124 "Extract attachment from message number MSG-NUM in the thread for
125 the bug with the given ID. Follow PATH to get to the correct
126 multipart chunk containing the attachment. This is absolutely
127 horrible because Debbugs does not let us access messages directly, so
128 we have to do this in a very convoluted way."
129 (define (nth n lst)
130 (and (< n (length lst))
131 (list-ref lst n)))
132 (define (traverse path parts)
133 (let loop ((path path)
134 (parts parts))
135 (match path
136 ((pos) (nth pos parts))
137 ((pos . rest)
138 (loop rest
139 (and=> (nth pos parts)
140 mime-entity-body))))))
141 (and=> (fetch-bug id)
142 (lambda (bug)
143 (and=> (nth msg-num (patch-messages id))
144 (lambda (msg)
145 (cond
146 ((multipart-message? msg)
147 (traverse path (email-body msg)))
148 (else
149 (match path
150 (() msg)
151 (_ #f)))))))))
152
153 \f
154 (define (download-message bug-id msg-num)
155 "Download message number MSG-NUM of bug BUG-ID and store it in the
156 mail directory if it's not already there. Return the name of the
157 target file."
158 (let ((key (list 'download-message bug-id msg-num)))
159 (or (cached? key)
160 (cache! key
161 (let ((file-name (format #f "~a/cur/~a-~a"
162 (%config 'mail-dir)
163 bug-id msg-num)))
164 (if (file-exists? file-name) file-name
165 (begin
166 (format (current-error-port)
167 "downloading ~a~%" file-name)
168 (call-with-values
169 (lambda ()
170 (fetch-mbox (%config 'debbugs)
171 bug-id msg-num #:streaming? #t))
172 (lambda (response port)
173 (with-output-to-file file-name
174 (lambda ()
175 (put-bytevector (current-output-port)
176 (get-bytevector-all port))))
177 (close-port port)))
178 file-name)))))))
179
180 ;; We would like to use get-bug-log here, but it often returns
181 ;; truncated messages. This is a known bug upstream.
182 (define-public (patch-messages bug-id)
183 "Return list of messages relating to the bug BUG-ID. Cache the
184 result for a while."
185 (let ((key (list 'patch-messages bug-id)))
186 (or (cached? key)
187 (cache! key
188 (match
189 (soap-invoke* (%config 'debbugs) get-bug-message-numbers bug-id)
190 ((msg-nums . _)
191 (map (lambda (msg-num)
192 (with-input-from-file (download-message bug-id msg-num)
193 (lambda ()
194 (match (mbox->emails (current-input-port))
195 ((email) (parse-email email))
196 (_ #f)))))
197 msg-nums)))))))
198
199 (define* (search-bugs query #:key (sets '()) (max 100))
200 "Return a list of all bugs matching the given QUERY string.
201 Interset the result with the id sets in the list SETS."
202 (let* ((ids (delete-duplicates
203 (map (compose string->number mu:bugid)
204 (mu:message-list query))))
205 (filtered (match sets
206 (() ids)
207 (_ (apply lset-intersection eq? ids sets)))))
208 (status-with-cache (if (> (length filtered) max)
209 (take filtered max) filtered))))
210
211 ;; TODO: This returns *any* matching debbugs bug, even if it is not
212 ;; part of the default packages.
213 (define (fetch-bug id)
214 "Return the bug matching ID or #F."
215 (match (soap-invoke* (%config 'debbugs) get-status (list id))
216 (() #f)
217 ((bug) bug)))
218
219 (define (recent-bugs amount)
220 "Return up to AMOUNT bugs with most recent activity."
221 (let* ((recent-ids
222 (delete-duplicates
223 (map (compose string->number mu:bugid)
224 (mu:message-list (string-append "date:1m..")))))
225 (ids (take recent-ids (min amount (length recent-ids)))))
226 (status-with-cache ids)))
227
228 (define (easy-bugs)
229 "Return all bugs that have been tagged \"easy\"."
230 (let ((ids (db:bugs-by-tag "easy")))
231 (status-with-cache ids)))
232
233 (define* (bugs-by-severity severity #:optional status)
234 "Return severe bugs."
235 (let* ((severity-ids (db:bugs-by-severity severity))
236 (ids (if status
237 (let ((status-ids (db:bugs-by-status status)))
238 (lset-intersection eq? severity-ids status-ids))
239 severity-ids)))
240 (status-with-cache ids)))
241
242 (define punctuation?
243 (cut char-set-contains? char-set:punctuation <>))
244
245 (define-public (process-query query)
246 "Process the QUERY string and return a list of query terms and
247 sets that need to overlap the result set."
248 ;; Mu doesn't like punctuation. Replace with spaces.
249 (define (clean-term term)
250 (string-map (match-lambda
251 ((? punctuation? c) #\space)
252 (c c))
253 term))
254 (fold (lambda (term acc)
255 (match acc
256 ((#:terms terms
257 #:sets fs)
258 (match (string-split term #\:)
259 ;; This is not supported by the Debbugs SOAP service,
260 ;; so we filter locally.
261 (("is" (or "done" "closed"))
262 `(#:terms ,terms
263 #:sets ,(cons (db:bugs-by-status "done") fs)))
264 (("is" (or "open" "pending"))
265 `(#:terms ,terms
266 #:sets ,(cons (db:bugs-by-status "open") fs)))
267 (("date" when)
268 `(#:terms ,(cons (string-append "date:" when) terms)
269 #:sets ,fs))
270 ;; TODO: this should only be the title of the bug, not
271 ;; the subject.
272 (("title" title)
273 `(#:terms
274 ,(cons (string-append "subject:" (clean-term title))
275 terms)
276 #:sets ,fs))
277 (("subject" subject)
278 `(#:terms
279 ,(cons (string-append "subject:" (clean-term subject))
280 terms)
281 #:sets ,fs))
282 (("tag" tag)
283 `(#:terms ,terms
284 #:sets
285 ,(cons (db:bugs-by-tag (clean-term tag)) fs)))
286 (("author" who)
287 `(#:terms
288 ,(cons (string-append "from:" (clean-term who)) terms)
289 #:sets ,fs))
290 (("owner" who)
291 `(#:terms ,terms
292 #:sets ,(cons (db:bugs-by-owner who) fs)))
293 (("submitter" who)
294 `(#:terms ,terms
295 #:sets ,(cons (db:bugs-by-submitter who) fs)))
296 (("severity" level)
297 `(#:terms ,terms
298 #:sets ,(cons (db:bugs-by-severity level) fs)))
299 ((whatever term)
300 `(#:terms ,(cons (clean-term term) terms)
301 #:sets ,fs))
302 (_
303 `(#:terms ,(cons (clean-term term) terms)
304 #:sets ,fs))))))
305 '(#:terms () #:sets ())
306 (string-tokenize query)))